[Greenbuilding] Comfort and shutters

Fri Nov 19 18:55:53 CST 2010

I will take a step back here and try and try and rephrase what I was trying
to say earlier. I know temperature flows can be modelled predicatively and
also that ashrae has a standard for thermal comfort that includes a lot of
studies but also a lot of reservations concerning subjectivity of human
comfort (which is what we are talking about). If we were just making an
unoccupied room comfortable for its own sake (as if rooms complain) then
balancing heatloss by raising the temp a degree might accomplish something

Now some of the interior walls or objects might complain about the 1 degree
rise if they were more comfortable at 70 but they can argue with the window
or some object near the window who might not feel that 1 degree is
sufficient.

Now I am that object near the window sitting on my panang (I just realized
that bald people probably have a less active hypothalamus and better brain
function - but I'm not balding yet - just envious). My panang (I now know
what that is - thanks to google) has been sitting by itself by the window
all day so is a few degrees less than 70. I'm looking forward to sitting
here as I have a new exciting ASHRAE standard that I am pretty keen to read
through so am not about to get up. In complying with the John Straub 'naked
man specification - NMS-1) there is little between me and the window (though
my rear is covered by a slightly cooled panang). 

Now I had raised the thermostat 1 degree to compensate for my comfort as an
NMS-1 and as per ASHRAE - at my favourite place by the window view (good
light too). I can't say I was entirely comfortable and noticed that my skin
was showing signs of piloerection (goosebumps) while other parts were not
and were actually retracting and my overall body was shivering slightly. 

Now despite the fact that my body is producing heat (3-400 btu/hr or so) I
realized that my body was feeling the difference and starting to compensate
dramatically and that that wouldn't be the ideal 'comfort' condition for
reading ASHRAE. So not wanting to move - I asked my partner to turn the heat
up. 

Now away from the window (having turned up the heat) most inanimate objects
are within a degree or two of 70. Now my partner is going through hormonal
changes that can push body temperature up as much as 6degC and she is not
currently in compliance with NMS-1 or even NFS-1 so feeling the affects of
both ASHRAE comfort standards and some subjective overheating refuses to
comply with my request and actually requires me to change my status to a
Clothed Male - CMS-1 (preferably with sweater).

What I do is forsake the view and move my panang next to the nearest radiant
heater.

JOHN SALMEN ENVIRONMENTAL DESIGN

4465 UPHILL RD,. DUNCAN, B.C.  CANADA, V9L 6M7

PH 250 748 7672 FAX 250 748 7612 CELL 250 246 8541

terrain at shaw.ca

  _____  

From: greenbuilding-bounces at lists.bioenergylists.org
[mailto:greenbuilding-bounces at lists.bioenergylists.org] On Behalf Of nick
pine
Sent: November 19, 2010 1:29 PM
To: greenbuilding at lists.bioenergylists.org
Subject: Re: [Greenbuilding] Comfort and shutters

< <mailto:terrain at shaw.ca> terrain at shaw.ca> writes:

> Pretty hard to model air movement

If a 70 F room is 20'x20' with 4'x8' of 56 F glass on one side 

and a (4x56+16x70)/20 = 67.2 average temp on that wall and

the opposite wall is 70 F with 16.6x10x20sqrt(8'(70-67.2))

= 15.7K cfm of convective airflow and a 15.7K/200 = 79 lfm

air velocity, it looks like we have to raise the room temp
ALMOST ONE FULL DEGREE F! :-)

20 CLO = 1'clothing insulation (clo)
30 MET=1.1'metabolic rate (met)
40 WME=0'external work (met)
50 RH=50'relative humidity (%)
60 DATA 70.767,56,70,63
70 FOR CASE=0 TO 1
80 READ TAF,TWF'air and glass/shutter temps (F)
90 TA=(TAF-32)/1.8'air temp (C)
100 TW=(TWF-32)/1.8'glass/shutter temp (C)
110 TR=.9866*TA+.0133*TW'mean radiant temp (C)
120 TWW=(4*TWF+16*70)/20'average window wall temp (F)
130 CFM=16.6*10*20*SQR(70-TWW)'convective cfm
140 VEL=CFM/200/196.9'air velocity (m/s)
150 PA=0'water vapor pressure
160 DEF FNPS(T)=EXP(16.6536-4030.183/(TA+235))'sat vapor pressure, kPa
170 IF PA=0 THEN PA=RH*10*FNPS(TA)'water vapor pressure, Pa
180 ICL=.155*CLO'clothing resistance (m^2K/W)
190 M=MET*58.15'metabolic rate (W/m^2)
200 W=WME*58.15'external work in (W/m^2)
210 MW=M-W'internal heat production
220 IF ICL<.078 THEN FCL=1+1.29*ICL ELSE FCL=1.05+.645*ICL'clothing factor
230 HCF=12.1*SQR(VEL)'forced convection conductance
240 TAA=TA+273'air temp (K)
250 TRA=TR+273'mean radiant temp (K)
260 TCLA=TAA+(35.5-TA)/(3.5*(6.45*ICL+.1))'est clothing temp
270 P1=ICL*FCL:P2=P1*3.96:P3=P1*100:P4=P1*TAA'intermediate values
280 P5=308.7-.028*MW+P2*(TRA/100)^4
290 XN=TCLA/100
300 XF=XN
310 N=0'number of iterations
320 EPS=.00015'stop iteration when met
330 XF=(XF+XN)/2'natural convection conductance
340 HCN=2.38*ABS(100*XF-TAA)^.25
350 IF HCF>HCN THEN HC=HCF ELSE HC=HCN
360 XN=(P5+P4*HC-P2*XF^4)/(100+P3*HC)
370 N=N+1
380 IF N>150 GOTO 510
390 IF ABS(XN-XF)>EPS GOTO 330
400 TCL=100*XN-273'clothing surface temp (C)
410 HL1=.00305*(5733-6.99*MW-PA)'heat loss diff through skin
420 IF MW>58.15 THEN HL2=.42*(MW-58.15) ELSE HL2=0'heat loss by sweating
430 HL3=.000017*M*(5867-PA)'latent respiration heat loss
440 HL4=.0014*M*(34-TA)'dry respiration heat loss
450 HL5=3.96*FCL*(XN^4-(TRA/100)^4)'heat loss by radiation
460 HL6=FCL*HC*(TCL-TA)'heat loss by convection
470 TS=.303*EXP(-.036*M)+.028'thermal sensation transfer coefficient
480 PMV=TS*(MW-HL1-HL2-HL3-HL4-HL5-HL6)'predicted mean vote
490 PPD=100-95*EXP(-.03353*PMV^4-.2179*PMV^2)'predicted % dissatisfied
500 GOTO 520
510 PMV=99999!:PPD=100
520 PRINT 600+CASE"'";TWF,TAF,PMV
530 NEXT CASE
540 LIST 60
550 'Innova AirTech Instruments has an excellent comfort web site...
560 'http://www.impind.de.unifi.it/Impind/didattica/materiale/
570 'microclima/innova/thermal.htm

56      70.767       -.3222994
63      70           -.322392

Passiv Haus fascists tend to overrate mean radiant temperatures.   

Nick

-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://lists.bioenergylists.org/pipermail/greenbuilding_lists.bioenergylists.org/attachments/20101119/3549adff/attachment.html>