[Greenbuilding] An annotated St. Louis TMY2 simulation

[nick pine]

PE Drew Gillett writes::

>one of the easiest ways to extend practical solar savings fractions 
>above .5 is to add night insulation to the apertures,  this gets you 
>to .8 or so.   the last 20% does require quite a bit of heroics 
>(storage) so more active systems with big stores and little night 
>loss are in order.

Few people are willing to move R20 window insulation twice a day for 
22 years. That might change... Someday, people might cover 2 dozen 
windows with thick shutters evey night as naturally as they put coats 
on when going outdoors on cold days. I wouldn't mind doing that twice 
a year vs twice a day, but I prefer simple automatic systems.

>one interesting aspect is that even on the darkest of days (no sun , 
>but daylight) , good solar glass breaks even down to about 20 , not 
>to mention the value of daylight as light/.    20 btuh/sq.ft incident 
>on r 2 glass handles 40 degrees or more of delta t/. thru the 
>daylight hours/.

R2 glass with 80% transmission and 0.8x20 = (70-T)1ft^2/R2 would make 
the outdoor temp T = 38 F, for a few hours a day.

>know anyone needing a ride (flight) from sunny fl to snowy nh next 
>week?

Fly into Perkiomen Valley, if you like. My 3-story sunspace should be 
done soon.

Corwyn wrote:

>Johannes Martinez wrote:

>>... i wonder if there's a reason you didn't include losses through 
>>the floor,

> Losses through the floor are not negligible, they are just very 
> complicated to calculate.

The deep ground temp in St. Louis is 56.1 F. A 40'x60' R30 slab with 
good perimeter insulation might only lose (65-56.1)40x60//R30 = 712 
Btu/h.

John Straube jfstraube at gmail.com writes:

> Although there are always a lot of assumptions of how heat transfers 
> to the storage mass in the house and the tank of water (which in 
> practise has been found to be one of the limitations of standard 
> models) this is likely not far off of what would be needed to get a 
> 100% solar house.

The tank could be heated with bare hyrdronic collectors inside the air 
heater, eg Zomeworks Big Fins or Energie Solaire stainless steel 
selective surface roof/wall panels... 
http://www.energie-solaire.com/en/products_roof.htm

> To accomplish this, 48' of the 60 ft long fully exposed south-facing 
> house (no trees or neighbors please) would need to be covered with 
> air collectors.

I'd vote for integrated "solar siding" over lots of wall insulation, 
vs 6 4'x8' boxes. Where I live near Phila, 10' trees and neighbors 
would have to be 20' away from the south wall. OTOH, the air heater 
could be a steep south polycarbonate attic roof.

> Note that the house has about half the windows of a normal house of 
> 2400 sf, and would likely need to have R60 roof (cause that is 
> cheap) and maybe more R in walls and windows to make up for the heat 
> loss of air leakage, ventilation, and slab, although indoor 
> electrical use of 300-600 kWh/month should help make up for a lot of 
> that.

An R60 vs R40 ceiling (line 460 below) reduces the tank size from 1075 
to 719 gallons :-)

80 L=60'house length (ft)
90 W=40'house width (ft)
100 AWIND=96'window area (ft^2)
110 UWIND=.25'window U-value (Btu/h-F-ft^2)
120 GWIND=AWIND*UWIND'window conductance (Btu/h-F)
130 AWALL=8*2*(L+W)-AWIND'wall area (ft^2)
140 RWALL=30'wall R-value (h-F-ft^2/Btu)
150 GWALL=AWALL/RWALL'wall conductance (Btu/h-F)
160 RCEIL=60'ceiling R-value
170 GCEIL=L*W/RCEIL'ceiling conductance (Btu/h-F)
180 GH=GWIND+GWALL+GCEIL'house conductance (Btu/h-F)
190 CH=7000'inherent house capacitance (Btu/F)
200 AHA=384'air heater area (ft^2)
210 CW=719*8.33'warm store capacitance (Btu/F)
220 CFM=1000'fan cfm
230 RAH=2/AHA+1/CFM'air heater equivalent resistance
240 TW=110'initial warm store temp (F)
250 TH=70'initial house temp
260 TAMIN=100'initialize min outdoor temp (F)
270 FOR YEAR=1 TO 2
280 AHMIN=1000'min house temp (F)
290 OPEN "stlyear" FOR INPUT AS #1:LINE INPUT#1,H$
300 FOR H=1 TO 8760'TMY2 hours
310 INPUT#1,MONTH,DAY,HOUR,TA,WIND,TDP,SH,SS,SW,SN,SE
320 IH=(TH-TA)*GH'house heat loss (Btu/h)
330 TH=TH-IH/CH'new house temp
340 TTA=TA+2*.8*SS'Thevenin equivalent air heater temp (F)
350 IF HOUR<6 OR HOUR>22 THEN TT=60 ELSE TT=70'target temp
360 QHEAT=(TT-TH)*CH'house heating need
370 IF QHEAT<0 THEN QHEAT=0:GOTO 490'house needs no heat. Charge 
store?
380 IF TTA<TH GOTO 440'no ss heat available. Warm house with store?
390 IF TTA-QHEAT*RAH-TH<0 GOTO 410'partial sunspace heating
400 TH=TT:GOTO 490'full sunspace heating
410 IA=(TTA-TH)/RAH'partial sunspace heating (Btu/h)
420 TH=TH+IA/CH'new house temp
430 QHEAT=(TT-TH)*CH'heat required to reach target temp
440 AWARM=(TW-TH)*CW'available warmstore heat
450 IF AWARM<0 THEN GOTO 490'no warmstore heat available
460 IF QHEAT<AWARM THEN TH=TT:SHEAT=QHEAT:GOTO 480'full target heating
470 TH=TH+AWARM/CH:SHEAT=AWARM'partial target heating
480 TW=TW-SHEAT/CW'new warmstore temp (F)
490 IF TTA-QHEAT*RAH<TW GOTO 540'no heat available for warmstore
500 QWARM=(140-TW)*CW'warmstore heating need (Btu)
510 IF QWARM<0 GOTO 540'warmstore needs no heat
520 IW=(TTA-QHEAT*RAH-TW)/RAH'warmstore charging (Btu/h)
530 IF IW<QWARM THEN TW=TW+IW/CW ELSE TW=140'new warmstore temp
540 IF TH<AHMIN THEN AHMIN=TH'min house temp (F)...

660 PRINT "2000'";CH,AHA,GH,TAMIN
670 PRINT "2010'";CW,TW,AHMIN
680 LIST 210

7000     384           114.1333     -4.000127E-02
5989.27                101.3548      60

Adding 30 cfm of air leaks with a mechanical ventilatiion system and 
no ERV (less expensive) and 712 Btu/h of slab loss and 300 kWh/mo of 
indoor electrical use reduces the tank size to 694 gallons...

210 LSLAB=712'slab heat loss (Btu/h)
220 EGAIN=300/30*3412/24'indoor electrical gain (Btu/h)
230 CGAIN=EGAIN-SLOSS'constant heat gain (Btu/h)...

340 FOR H=1 TO 8760'TMY2 hours
350 INPUT#1,MONTH,DAY,HOUR,TA,WIND,TDP,SH,SS,SW,SN,SE
360 IH=(TH-TA)*GH-CGAIN'house heat loss (Btu/h)
370 TH=TH-IH/CH'new house temp

7000     384           144.1333     -4.000127E-02
5781.02                104.3704      60

> Once such a well insulated airtight house has been built and all the 
> space heating load avoided by using solar mass and indoor 
> temperature swings, the energy bills from the domestic hotwater and 
> electric use would still be pretty big.  Hence why many designs 
> aiming for low energy use / low energy cost have ended up trying to 
> combine a solar hotwater collection system with a space heating 
> system:

Solar hot water can pay for itself every day of the year...

>I cant see what SHGC you used for the windows (I think you did not 
>include this heating source).

I didn't count direct gain from windows.

>What happens if you put about 150-200 sf of good windows (U=.2, 
>SHGC=0.6) on the south, and 150 sf on the other three sides of your 
>2400 sq foot house?

That decreases the tank size from 694 to to 430 gallons. How much does 
it add to the cost of the house, $40x200ft^2, including labor?

80 L=60'house length (ft)
90 W=40'house width (ft)
100 SWIND=150'south window area (ft^2)
110 WWIND=50'west window area (ft^2)
120 NWIND=50'north window area (ft^2)
130 EWIND=50'east window area (ft^2)
140 AWIND=SWIND+WWIND+NWIND+EWIND'total window area (ft^2)
150 UWIND=.2'window U-value (Btu/h-F-ft^2)
160 GWIND=AWIND*UWIND'window conductance (Btu/h-F)
170 AWALL=8*2*(L+W)-AWIND'wall area (ft^2)
180 RWALL=30'wall R-value (h-F-ft^2/Btu)
190 GWALL=AWALL/RWALL'wall conductance (Btu/h-F)
200 RCEIL=60'ceiling R-value
210 GCEIL=L*W/RCEIL'ceiling conductance (Btu/h-F)
220 GAIR=30'air leakage (cfm)
230 GH=GAIR+GWIND+GWALL+GCEIL'house conductance (Btu/h-F)
240 CH=7000'inherent house capacitance (Btu/F)
250 LSLAB=712'slab heat loss (Btu/h)
260 EGAIN=300/30*3412/24'indoor electrical gain (Btu/h)
270 CGAIN=EGAIN-SLOSS'constant heat gain (Btu/h)
280 AHA=384'air heater area (ft^2)
290 CW=430*8.33'warm store capacitance (Btu/F)
300 CFM=1000'fan cfm
310 RAH=2/AHA+1/CFM'air heater equivalent resistance
320 TW=110'initial warm store temp (F)
330 TH=70'initial house temp
340 TAMIN=100'initialize min outdoor temp (F)
350 FOR YEAR=1 TO 2
360 AHMIN=1000'min house temp (F)
370 OPEN "stlyear" FOR INPUT AS #1:LINE INPUT#1,H$
380 FOR H=1 TO 8760'TMY2 hours
390 INPUT#1,MONTH,DAY,HOUR,TA,WIND,TDP,SH,SS,SW,SN,SE
400 WGAIN=.6*(SS*SWIND+SW*WWIND+SN*NWIND+SE*EWIND)'window gain
410 IH=(TH-TA)*GH-WGAIN-CGAIN'house heat loss (Btu/h)
420 TH=TH-IH/CH'new house temp
430 TTA=TA+2*.8*SS'Thevenin equivalent air heater temp (F)
440 IF HOUR<6 OR HOUR>22 THEN TT=60 ELSE TT=70'target temp
450 QHEAT=(TT-TH)*CH'house heating need
460 IF QHEAT<0 THEN QHEAT=0:GOTO 580'house needs no heat. Charge 
store?
470 IF TTA<TH GOTO 530'no ss heat available. Warm house with store?
480 IF TTA-QHEAT*RAH-TH<0 GOTO 500'partial sunspace heating
490 TH=TT:GOTO 580'full sunspace heating
500 IA=(TTA-TH)/RAH'partial sunspace heating (Btu/h)
510 TH=TH+IA/CH'new house temp
520 QHEAT=(TT-TH)*CH'heat required to reach target temp
530 AWARM=(TW-TH)*CW'available warmstore heat
540 IF AWARM<0 THEN GOTO 580'no warmstore heat available
550 IF QHEAT<AWARM THEN TH=TT:SHEAT=QHEAT:GOTO 570'full target heating
560 TH=TH+AWARM/CH:SHEAT=AWARM'partial target heating
570 TW=TW-SHEAT/CW'new warmstore temp (F)
580 IF TTA-QHEAT*RAH<TW GOTO 630'no heat available for warmstore
590 QWARM=(140-TW)*CW'warmstore heating need (Btu)
600 IF QWARM<0 GOTO 630'warmstore needs no heat
610 IW=(TTA-QHEAT*RAH-TW)/RAH'warmstore charging (Btu/h)
620 IF IW<QWARM THEN TW=TW+IW/CW ELSE TW=140'new warmstore temp
630 IF TH<AHMIN THEN AHMIN=TH'min house temp (F)...

750 PRINT "2000'";CH,AHA,GH,TAMIN
760 PRINT "2010'";CW,TW,AHMIN
770 LIST 290

7000     384           173.3333     -4.000127E-02
3581.9   110.2576      60

>St Louis is a relatively mild climate. Lambert airport has 4500 HDD 
>65.   What about a cold place, like Syracuse, or Buffalo or even 
>Minneapolis?

A 472 gallon tank works in Minneapolis, with the help of an 80% HRV, 
or a bidirectional lung, which might be built into the solar siding:

80 L=60'house length (ft)
90 W=40'house width (ft)
100 AWIND=96'window area (ft^2)
110 UWIND=.2'window U-value (Btu/h-F-ft^2)
120 GWIND=AWIND*UWIND'window conductance (Btu/h-F)
130 AWALL=8*2*(L+W)-AWIND'wall area (ft^2)
140 RWALL=30'wall R-value (h-F-ft^2/Btu)
150 GWALL=AWALL/RWALL'wall conductance (Btu/h-F)
160 RCEIL=60'ceiling R-value
170 GCEIL=L*W/RCEIL'ceiling conductance (Btu/h-F)
180 FCFM=30'fresh air supply (cfm)
190 GAIR=.2*FCFM'equivalent ventilation concutance
200 GH=GAIR+GWIND+GWALL+GCEIL'house conductance (Btu/h-F)
210 CH=7000'inherent house capacitance (Btu/F)
220 LSLAB=2400/30*(65-44.9)'slab heat loss (Btu/h)
230 EGAIN=300/30*3412/24'indoor electrical gain (Btu/h)
240 CGAIN=EGAIN-SLOSS'constant heat gain (Btu/h)
250 AHA=384'air heater area (ft^2)
260 CW=472*8.33'warm store capacitance (Btu/F)
270 CFM=1000'fan cfm
280 RAH=2/AHA+1/CFM'air heater equivalent resistance
290 TW=110'initial warm store temp (F)
300 TH=70'initial house temp
310 TAMIN=100'initialize min outdoor temp (F)
320 FOR YEAR=1 TO 2
330 AHMIN=1000'min house temp (F)
340 OPEN "minyear" FOR INPUT AS #1:LINE INPUT#1,H$
350 FOR H=1 TO 8760'TMY2 hours
360 INPUT#1,MONTH,DAY,HOUR,TA,WIND,TDP,SH,SS,SW,SN,SE
365 WGAIN=.6*AWIND*SS
370 IH=(TH-TA)*GH-WGAIN-CGAIN'house heat loss (Btu/h)
380 TH=TH-IH/CH'new house temp
390 TTA=TA+2*.8*SS'Thevenin equivalent air heater temp (F)
400 IF HOUR<6 OR HOUR>22 THEN TT=60 ELSE TT=70'target temp
410 QHEAT=(TT-TH)*CH'house heating need
420 IF QHEAT<0 THEN QHEAT=0:GOTO 540'house needs no heat. Charge 
store?
430 IF TTA<TH GOTO 490'no ss heat available. Warm house with store?
440 IF TTA-QHEAT*RAH-TH<0 GOTO 460'partial sunspace heating
450 TH=TT:GOTO 540'full sunspace heating
460 IA=(TTA-TH)/RAH'partial sunspace heating (Btu/h)
470 TH=TH+IA/CH'new house temp
480 QHEAT=(TT-TH)*CH'heat required to reach target temp
490 AWARM=(TW-TH)*CW'available warmstore heat
500 IF AWARM<0 THEN GOTO 540'no warmstore heat available
510 IF QHEAT<AWARM THEN TH=TT:SHEAT=QHEAT:GOTO 530'full target heating
520 TH=TH+AWARM/CH:SHEAT=AWARM'partial target heating
530 TW=TW-SHEAT/CW'new warmstore temp (F)
540 IF TTA-QHEAT*RAH<TW GOTO 590'no heat available for warmstore
550 QWARM=(140-TW)*CW'warmstore heating need (Btu)
560 IF QWARM<0 GOTO 590'warmstore needs no heat
570 IW=(TTA-QHEAT*RAH-TW)/RAH'warmstore charging (Btu/h)
580 IF IW<QWARM THEN TW=TW+IW/CW ELSE TW=140'new warmstore temp
590 IF TH<AHMIN THEN AHMIN=TH'min house temp (F)
710 PRINT "2000'";CH,AHA,GH,TAMIN...

720 PRINT "2010'";CW,TW,AHMIN
730 LIST 260

7000     384           115.3333     -20.92
3931.76                136.4655      60

Nick