[Greenbuilding] Comfort and shutters

Fri Nov 19 07:17:03 CST 2010

Alan Abrams <alan at abramsdesignbuild.com> asks:

>... is comfort a (partial) function of radiant heat loss to
> 
> 1. surfaces of lower temperature--in this case the cardboard, newspaper,
> bubble wrap or shade--vs a single pane of glass at near ambient temp.

Yes.

> 2. a radiant-transparent/transluscent membrane, with cold surfaces/cold
> space beyond

Yes, if the surface is transparent to IR, eg polyethylene film.
No, if the surface is opaque to IR, eg glass. You can try
holding each between you and a stove burner.

> In other words, is comfort completely attributable to measurable thermal
> conductance, or is some quotient that is not attributable to assembly
> R-values?

ASHRAE says comfort http://en.wikipedia.org/wiki/Thermal_comfort is
a function of air temp and RH, mean radiant temp (which includes window
glass temps), air velocity, amount of clothing, and human activity level.

If it's 70 F indoors and 30 outdoors, an unshuttered R2 window will have
a 56 F indoor glass temp. An R2 shutter over the window will have
a 63 F indoor shutter temp. In the first case, a person in the center 
of a cubical room with 8% of the floorspace as windows will see
a 0.9866x70+0.0133x56 = 69.81 mean radiant temp. With shutters,
the person will see a 69.91 mean radiant temp :-)

Cranking this into the BASIC program in the ASHRAE 55-2004
comfort standard...

20 CLO = 1'clothing insulation (clo)
30 MET=1.1'metabolic rate (met)
40 WME=0'external work (met)
50 VEL=.1'air velocity
60 RH=50'relative humidity (%)
70 DATA 70.043,56,70,63
80 FOR CASE=0 TO 1
90 READ TAF,TWF'air and glass/shutter temps (F)
100 TA=(TAF-32)/1.8'air temp (C)
110 TW=(TWF-32)/1.8'glass/shutter temp (C)
120 TR=.9866*TA+.0133*TW'mean radiant temp (C)
130 PA=0'water vapor pressure
140 DEF FNPS(T)=EXP(16.6536-4030.183/(TA+235))'sat vapor pressure, kPa
150 IF PA=0 THEN PA=RH*10*FNPS(TA)'water vapor pressure, Pa
160 ICL=.155*CLO'clothing resistance (m^2K/W)
170 M=MET*58.15'metabolic rate (W/m^2)
180 W=WME*58.15'external work in (W/m^2)
190 MW=M-W'internal heat production
200 IF ICL<.078 THEN FCL=1+1.29*ICL ELSE FCL=1.05+.645*ICL'clothing factor
210 HCF=12.1*SQR(VEL)'forced convection conductance
220 TAA=TA+273'air temp (K)
230 TRA=TR+273'mean radiant temp (K)
240 TCLA=TAA+(35.5-TA)/(3.5*(6.45*ICL+.1))'est clothing temp
250 P1=ICL*FCL:P2=P1*3.96:P3=P1*100:P4=P1*TAA'intermediate values
260 P5=308.7-.028*MW+P2*(TRA/100)^4
270 XN=TCLA/100
280 XF=XN
290 N=0'number of iterations
300 EPS=.00015'stop iteration when met
310 XF=(XF+XN)/2'natural convection conductance
320 HCN=2.38*ABS(100*XF-TAA)^.25
330 IF HCF>HCN THEN HC=HCF ELSE HC=HCN
340 XN=(P5+P4*HC-P2*XF^4)/(100+P3*HC)
350 N=N+1
360 IF N>150 GOTO 490
370 IF ABS(XN-XF)>EPS GOTO 310
380 TCL=100*XN-273'clothing surface temp (C)
390 HL1=.00305*(5733-6.99*MW-PA)'heat loss diff through skin
400 IF MW>58.15 THEN HL2=.42*(MW-58.15) ELSE HL2=0'heat loss by sweating
410 HL3=.000017*M*(5867-PA)'latent respiration heat loss
420 HL4=.0014*M*(34-TA)'dry respiration heat loss
430 HL5=3.96*FCL*(XN^4-(TRA/100)^4)'heat loss by radiation
440 HL6=FCL*HC*(TCL-TA)'heat loss by convection
450 TS=.303*EXP(-.036*M)+.028'thermal sensation transfer coefficient
460 PMV=TS*(MW-HL1-HL2-HL3-HL4-HL5-HL6)'predicted mean vote
470 PPD=100-95*EXP(-.03353*PMV^4-.2179*PMV^2)'predicted % dissatisfied
480 GOTO 500
490 PMV=99999!:PPD=100
500 PRINT 600+CASE"'";TWF,TAF,PMV
510 NEXT CASE
515 LIST 70
520 'Innova AirTech Instruments has an excellent comfort web site...
530 'http://www.impind.de.unifi.it/Impind/didattica/materiale/
540 'microclima/innova/thermal.htm

56      70.043       -.3230851
63      70           -.3230717 

... it looks like we only have to raise the unshuttered room air temp
from 70 to 70.043 F to make the rooms equally comfortable, unless you
are sitting right next to a window.

Passiv Haus fascists seem to overemphasize the effect of mean radiant
temps on comfort.

Nick
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://lists.bioenergylists.org/pipermail/greenbuilding_lists.bioenergylists.org/attachments/20101119/4a4bd7f3/attachment.html>