[Greenbuilding] An annotated St. Louis TMY2 simulation

[nick pine]

>Heating 50 gallons per day of water raises the Minneapolis tank size 
>to 740 gallons...

In this simulation, an electric postheater reduces the tank size to 
660 gallons, eg a 4'x8'x3' tall plywood box with a folded EPDM liner 
with a 1"x300' 13-gallon pressurized plastic pipe coil heat exchanger 
and an electric water heating element and 140 F thermostat near the 
top.

80 L=60'house length (ft)
90 W=40'house width (ft)
100 AWIND=96'window area (ft^2)
110 UWIND=.2'window U-value (Btu/h-F-ft^2)
120 GWIND=AWIND*UWIND'window conductance (Btu/h-F)
130 AWALL=8*2*(L+W)-AWIND'wall area (ft^2)
140 RWALL=30'wall R-value (h-F-ft^2/Btu)
150 GWALL=AWALL/RWALL'wall conductance (Btu/h-F)
160 RCEIL=60'ceiling R-value
170 GCEIL=L*W/RCEIL'ceiling conductance (Btu/h-F)
180 FCFM=30'fresh air supply (cfm)
190 GAIR=.2*FCFM'equivalent ventilation concutance
200 GH=GAIR+GWIND+GWALL+GCEIL'house conductance (Btu/h-F)
210 CH=7000'inherent house capacitance (Btu/F)
220 TG=44.9'deep ground temp (F)
230 LSLAB=2400/30*(65-TG)'slab heat loss (Btu/h)
240 WCON=50'hot water consumption (gpd)
250 TDHW=110'hot water temp (F)
260 CDHW=WCON*8.33/24'water heating capacity rate (Btu/h-F)
270 EGAIN=300/30*3412/24'indoor electrical gain (Btu/h)
280 CGAIN=EGAIN-SLOSS'constant heat gain (Btu/h)
290 AHA=384'air heater area (ft^2)
300 CW=660*8.33'warm store capacitance (Btu/F)
310 CFM=1000'fan cfm
320 RAH=2/AHA+1/CFM'air heater equivalent resistance
330 TW=110'initial warm store temp (F)
340 TH=70'initial house temp
350 TAMIN=100'initialize min outdoor temp (F)
360 FOR YEAR=1 TO 2
370 AHMIN=1000'min house temp (F)
380 EDHW=0'initialize electrical water heating energy
390 OPEN "minyear" FOR INPUT AS #1:LINE INPUT#1,H$
400 FOR H=1 TO 8760'TMY2 hours
410 INPUT#1,MONTH,DAY,HOUR,TA,WIND,TDP,SH,SS,SW,SN,SE
420 WGAIN=.6*AWIND*SS
430 IH=(TH-TA)*GH-WGAIN-CGAIN'house heat loss (Btu/h)
440 TH=TH-IH/CH'new house temp
450 TTA=TA+2*.8*SS'Thevenin equivalent air heater temp (F)
460 IF HOUR<6 OR HOUR>22 THEN TT=60 ELSE TT=70'target temp
470 QHEAT=(TT-TH)*CH'house heating need
480 IF QHEAT<0 THEN QHEAT=0:GOTO 600'house needs no heat. Charge 
store?
490 IF TTA<TH GOTO 550'no ss heat available. Warm house with store?
500 IF TTA-QHEAT*RAH-TH<0 GOTO 520'partial sunspace heating
510 TH=TT:GOTO 600'full sunspace heating
520 IA=(TTA-TH)/RAH'partial sunspace heating (Btu/h)
530 TH=TH+IA/CH'new house temp
540 QHEAT=(TT-TH)*CH'heat required to reach target temp
550 AWARM=(TW-TH)*CW'available warmstore space heat
560 IF AWARM<0 THEN GOTO 600'no warmstore space heat available
570 IF QHEAT<AWARM THEN TH=TT:SHEAT=QHEAT:GOTO 590'full space heating
580 TH=TH+AWARM/CH:SHEAT=AWARM'partial space heating
590 TW=TW-SHEAT/CW'new warmstore temp (F)
600 IF TW>TDHW THEN WHEAT=(TDHW-TG)*CDHW:GOTO 630'full water heating
610 WHEAT=(TW-TG)*CDHW'partial solar water heating
620 EDHW=EDHW+(TDHW-TW)*CDHW'electric makeup heating
630 TW=TW-WHEAT/CW'new warmstore temp (F)
640 IF TTA-QHEAT*RAH<TW GOTO 690'no ss heat available for warmstore
650 QWARM=(140-TW)*CW'warmstore heating need (Btu)
660 IF QWARM<0 GOTO 690'warmstore needs no heat
670 IW=(TTA-QHEAT*RAH-TW)/RAH'warmstore charging (Btu/h)
680 IF IW<QWARM THEN TW=TW+IW/CW ELSE TW=140'new warmstore temp
690 IF TH<AHMIN THEN AHMIN=TH'min house temp (F)...

810 WCOST=.1*EDHW/3412'water heating cost at 10 cents/kwh
820 PRINT "2000'";CH,AHA,GH,TAMIN
830 PRINT "2010'";CW,TW,AHMIN,WCOST
840 LIST 300

7000     384           115.3333     -20.92
5497.8   135.8284      60            7.384001

At 10 cents/kWh, the water heating energy only costs $7.38 per year.

Nick.